Archive of the former Yahoo!Groups mailing list: Korg Poly800/EX800 Users

OK, so I checked my code. Here are my comments in the assembler code for receiving NRPN:

; NRPN MSB followed by NRPN LSB then data value. No other sequence or combination is permitted.
; And NRPN MSB and LSB must be transmitted for each and every data value (ie: there is no NRPN running status).
; reception of the NRPN MSB always resets the NRPN sequence.

I wrote the code this way because it appears to be the most common implementation and is 100% reliable. Whereas, other implementations (such as your controller) result in ambiguous situations where MIDI NRPN controllers can be screwed up.

See http://www.philrees.co.uk/nrpnq.htm

I am willing to hear from others as to whether this is proper practice or not.

Perhaps I could be convinced to add a global parameter to allow changing the NRPN behavior.

Mike

And here is the actual assembler:

; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
; the MIDI NRPN controller messages are handled below
; the NRPN MSB received must match the global NRPN MSB (global 16) for any parameter change to occur
; in order to avoid overruns and stop RPN's from interfering with NRPN's, the sequence of NRPN MUST be
; NRPN MSB followed by NRPN LSB then data value. No other sequencer combination is permitted.
; And NRPN MSB and LSB must be transmitted for each and every data value (ie: there is no NRPN running status).
; reception of the NRPN MSB always resets the NRPN sequence
; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
MIDI_NRPN_MSB:
        mov    a, d
        sta    M_NRPN_MSB        ; save the NRPN MSB
        mvi    a, 2            ; set NRPN sequence to MSB received
        sta    M_NRPN_SEQUENCE
        jmp    MIDI_MODE_NO    ; end by reset of control change status
; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
MIDI_NRPN_LSB:
        lda    M_NRPN_SEQUENCE    ; get current NRPN sequence
        cpi    2            ; test for MSB received
        jnz    MIDI_MODE_NO    ; no MSB received so get out
        dcr    a            ; set A=1 (LSB received)
        sta    M_NRPN_SEQUENCE    ; save sequence flag
        mov    a, d            ; put MIDI Data value into A
        sta    M_NRPN_LSB        ; save the NRPN LSB
        jmp    MIDI_MODE_NO    ; end by reset of control change status
; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
MIDI_NRPN_DAT:
        lda    M_NRPN_SEQUENCE    ; get current NRPN sequence
        cpi    1            ; test for MSB and LSB received
        jnz    MIDI_MODE_NO    ; no MSB,LSB received so get out
        dcr    a            ; set A=0 (reset sequence flag)
        sta    M_NRPN_SEQUENCE    ; save sequence flag
        mov    a, d
        sta    M_NRPN_DATA        ; save the data value
        lda    M_NRPN_MSB        ; get the current NRPN MSB
        mov    b, a            ; put the current NRPN MSB into B
        lda    C_NRPN_MSB        ; get selected NRPN MSB (global 16)
        cmp    b            ; compare selected NRPN MSB to current NRPN MSB
        mvi    a, 1            ; preload A = true
        jz    MIDI_NRPN_SKIP    ; skip if selected MSB = current MSB
        xra    a            ; did not match therefore set changed flag = false
MIDI_NRPN_SKIP:
        sta    M_NRPN_CHANGE    ; save changed flag (will only change if NRPN MSB matches global)
        jmp    MIDI_MODE_NO    ; end by reset of control change status
; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~