[sdiy] CA3080 SPICE macromodel (was: SVF resonance...)

[Tim Stinchcombe]

Hi list,

> > I've got nonlinear asymetric digital models of a few 
> different filter
> > topololigies up and working including the SEM, but not a 
> full model of 
> > the CA3080, only a slightly asymetric Tanh one. Thanks to Antti for 
> > the help with getting me started down the road to proper analog 
> > modeling - he actually suggested I join this list as well.
> 
> I made a subcircuit for the 3080 using all 2N3904 /
> 3906
> transistors (including using them for the diodes !!!) It 
> works well in simulation, you might try it...

...and a few years ago I 'customized' the National LM13700 model to make it
look more like a CA3080. I've pasted it in below if anyone wants to have a
go with it.

The scrappy notes under 'features' are mine, just to remind myself what I
did/didn't do. It thus looks like I changed things that I could get from the
CA3080 datasheet, like o/p voltage swing, input/output capacitance, the
fewer  diodes at the Iabc pin, output resistance etc., but couldn't find
some things, input offset current etc., so they are omitted. Other than that
it runs, and should be good for AC analyses (at least in as much as the
LM13700 one is!). So some things are like the CA3080, but I have made
absolutely *NO* attempt to check it experimentally against the real thing,
so if/when using, always bear this in mind!!

(Someday when I get the time I'll write a more detailed note on what I did
and post on my website.)

Tim
__________________________________________________________
Tim Stinchcombe 

Cheltenham, Glos, UK
email: tim102 at tstinchcombe.freeserve.co.uk

* \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\            
* My attempt at CA3080 model                
* \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\ 
* Borrows heavily from National LM13700 model                
*
*               Amplifier Bias Input
*               | Positive Input
*               | | Negative Input
*               | | | Output
*               | | | | Negative power supply
*               | | | | | Positive power supply
*               | | | | | |
.SUBCKT CA3080  5 3 2 6 4 7
*
* Features:
* In and out capacitance taken from datasheet
* Ouput impedance gain constant also calculated from datasheet
* No input offset current - don't know proper device chars for that
* Stick with LM13700 transistors and diode?
* supply drain per se - couldn't see where LM figure from
* some extra diodes for different current mirror diode drops
* similarly, voltage offsets at output changed, V4, V5
* buffer obviously zapped, bias diodes too
* Don't get CMR bit - commented out
* F2, F4 gains set to unity
* all commented out are old nodes!
 
C1  4  2  3.5P
C2  3  4  3.5P
* Output capacitor  
C3  6  4  5.5P                                       
D3  7  21 DX
D2  21 20 DX
D4  20 22 DX
D5  5  27 DX
D7  6  29 DX
D8  28 6  DX
D10 31 25 DX
**** Clamp for -CMR  
***D11 28 25 DX                                        
**** Ios source 
***F1  4  3  POLY(1)   V6 1E-10 5.129E-2 -1.189E4 1.123E9 
F2  7  6  V2        1.0
F3  25 4  V3        1.0
F4  6  4  V1        1.0
* Output impedance 
F5  6  0  POLY(2)   V3 V7 0 0 0 0 1                  
G1  0  33 6  0      1.46E-4
***I1  11 6  300U
Q1  24 2  31        QX1
Q2  23 3  31        QX2
V1  22 24 0V
V2  22 23 0V
V3  27 4  0V
V4  7  29 2.1
V5  28 4  1.2
*** V6  4  32 0V      ***Ios related
V7  33 0  0V
.MODEL QX1 NPN (IS=5E-16     BF=200 NE=1.15 ISE=.63E-16 IKF=1E-2)
.MODEL QX2 NPN (IS=5.125E-16 BF=200 NE=1.15 ISE=.63E-16 IKF=1E-2)
.MODEL DX  D   (IS=5E-16)
.ENDS